周云的FLASH小游戏开发教室_基础篇（共11节） 接宝游戏中人物类的CLASS讲解

class player.Player_1 extends MovieClip { 
    private var hit:MovieClip; //人物MC里出现的东西都要声明，hit这个MC也不例外 
    public var speed:Number;//这个是人物移动的速度 
    //构造函数 
    function Player_1() { 
        init();//初始化的人物打包在init()里了 
    } 
    //隐式设置-获取法 
    public function set _speed(sss:Number):Void { 
        speed = sss; 
    }//可供外界用MC._speed=X修改speed的数值 
    public function get _speed():Number { 
        return (speed); 
    }//可供外界读取speed的数值 
    //私-公有方法 
    //---初始化方法--- 
    private function init() { 
        _y = 310; 
        _x = 300;//人物来到舞台后的初始位置 
        speed = 6;//移动速度 
        onEnterFrame = Move;//人物来到舞台后就开始onEnterFrame，内容见Move这个function 
    } 
    //---人物移动--- 
    private function Move() { 
        if (Key.isDown(37)) { 
            _xscale = -100; 
            _x -= speed; 
            this.gotoAndStop("run"); 
        } else if (Key.isDown(39)) { 
            _xscale = 100; 
            _x += speed; 
            this.gotoAndStop("run"); 
        } else { 
            this.gotoAndStop("stand"); 
        } 
        //以上是左右键的定义，应该看得懂吧？ 
        if (Key.isDown(38)) { 
            speed = 12; 
        } else { 
            speed = 6; 
        } 
                //以上是上键的定义，按着后速度就加倍咯 
        range();//范围定义，内容见下面 
    } 
    //---限定移动范围--- 
    private function range() {         
        if (_x>540) { 
            _x = 540; 
        } 
        if (_x<10) { 
            _x = 10; 
        }//不让人物出界 
    } 
}

class player.Player_2 extends player.Player_1 {
    //继承了player.Player_1类，所以只需要把两者间唯一不同的Move函数重写次就可以啦~当然构造函数还是要的
    function Player_2() {
        init();
    }
    //人物2的Move函数
    private function Move() {
        if (Key.isDown(37)) {
            _xscale = -100;
            _x -= speed;
            if (_currentframe != 3) {
                gotoAndStop("run");
            }//这句自己体会下，不加的话，按上键后鸣人就一直不停的在跳跃了
        } else if (Key.isDown(39)) {
            _xscale = 100;
            _x += speed;
            if (_currentframe != 3) {
                gotoAndStop("run");
            }
        } else {
            if (_currentframe != 3) {
                gotoAndStop("stand");
            }
        }
        //
        if (Key.isDown(38)) {
            gotoAndStop("jump");
        }
        range();
    }
}